DizzyAGE Book - 17. Cutscenes

17. CUTSCENES
non interactive sequences

About cutscenes

A cutscene is a non-interactive sequence that breaks the gameplay to usually present some story development. It can be also used as an introduction sequence, when the game begins, presenting the background of the story. Or, it can be used as an ending sequence, presenting a conclusion, a finish for the story. From simple to complex, these cutscenes are highly appreciated by adventure games players.

The simplest form of cutscene is made of a few dialog messages, told by the author, or as a conversation between game characters. Even if the player advances it, by pressing the action key, it is considered non-interactive, because the main character cannot be moved as usual. Complex cutscenes, also involve moving of objects, player and characters, like in a small movie.

There are no rules on how cutscenes are implemented. Some of them just change the tiles or work on their animations, others move the dynamic brushes or the player, or even simulate moving key combinations for the player.

Let's now have a cutscene example.
Start from the default template data and open the map in the editor.

Add in the second room, a dynamic brush representing Theo (x=864, y=216, tile=207, type=dynamic, id=1000).

Then add another dynamic brush representing a blue goat, in the first room (x=688, y=232, tile=166, color=ff0000ff, type=dynamic, id=1001, draw=0).

Save the map and add the following functions in the game.gs file. Start the game, enter the second room and enjoy the sequence! Then, try to understand it and check the reference and the content of the used functions.

func OpenRoom_3_1()
{
	ScrRequest(gs_fid("PlayCutscene"));
}

func PlayCutscene()
{
	// position player and avoid eventual jump entries
	PlayerSetPos(720,246);
	PlayerEnterIdle();
	
	// enter talk
	PlayerWalkTo(760);
	PlayerEnterIdle();
	Message1(3,4,"FINALLY!\nTHEO, THE WIZZARD!");MessagePop();
	idx = ObjFind(1000);
	ObjSet(idx,O_FLIP,1);
	Message2(12,6,"HELLO DIZZY!");MessagePop();
	
	// walk closer
	PlayerWalkTo(840);
	PlayerEnterIdle();
	Message1(6,4,"THEO, I WANT YOU\nTO MAKE ME RED!");MessagePop();
	Message2(12,6,"ARE YOU SURE,\n DIZZY?");MessagePop();
	Message1(4,3,"YES, I THINK RED\nIS A NICE COLOR\nFOR AN EGG...");
	MessagePop();
	Message2(10,4,"ALL RIGHT THEN,\nIF THAT'S WHAT\nYOU WISH FOR...");
	MessagePop();
	
	// theo animation
	ObjSet(idx,O_TILE,202);
	ObjSet(idx,O_W,40);	ObjSet(idx,O_H,40);
	ObjSet(idx,O_MAP+2,40);	ObjSet(idx,O_MAP+3,40);
	ObjSet(idx,O_X,ObjGet(idx,O_X)-13);
	ObjSet(idx,O_Y,ObjGet(idx,O_Y)+1);
	WaitFramesClearKeys(20);

	ObjSet(idx,O_TILE,206);
	ObjSet(idx,O_W,42);	ObjSet(idx,O_H,41);
	ObjSet(idx,O_MAP+2,42);	ObjSet(idx,O_MAP+3,41);
	ObjSet(idx,O_X,ObjGet(idx,O_X)-2);
	ObjSet(idx,O_Y,ObjGet(idx,O_Y)-1);
	WaitFramesClearKeys(10);
	
	// dizzy
	//PlayerEnterScripted();
	PlayerSet(P_EMOTION,EMOTION_NOAIR1);
	WaitFramesClearKeys(30);
	PlayerSet(P_EMOTION,EMOTION_NOAIR2);
	WaitFramesClearKeys(30);
	PlayerSet(P_EMOTION,EMOTION_NOAIR3);
	WaitFramesClearKeys(30);
	PlayerSet(P_EMOTION,0);
	
	// theo back
	ObjSet(idx,O_TILE,207);
	ObjSet(idx,O_W,27);	ObjSet(idx,O_H,41);
	ObjSet(idx,O_MAP+2,27);	ObjSet(idx,O_MAP+3,41);
	ObjSet(idx,O_X,ObjGet(idx,O_X)+15);

	// dizzy fall
	PlayerSet(P_COLOR,COLOR_RED);
	PlayerPlayAnim(PTILE_DEAD);
	Message2(10,4,"DIZZY!\nARE YOU\nALL RIGHT?");MessagePop();
	
	// dizzy wake
	PlayerPlayAnimFrames(PTILE_STUN,{0,1,0,1,0,1,0,1,2,3,2,3,2,3,2,3,4,4,4,4});
	PlayerEnterIdle();
	Message(4,6,"HURRAY!\nI'M ALL RED!",COLOR_RED,COLOR_RED);MessagePop();
	PlayerEnterJump(0,DIZ_POW);
	while(PlayerGet(P_STATUS)!=STATUS_IDLE) { ClearKeys(); stop; }
	WaitFramesClearKeys(20);

	// look left
	PlayerEnterScripted();
	PlayerSet(P_TILE,PlayerGet(P_TILEWALK));
	PlayerSet(P_FRAME,0);
	PlayerSet(P_FLIP,1);
	Message(14,7,"OH NO!",COLOR_RED,COLOR_RED); MessagePop();	
	PlayerEnterIdle();
	PlayerSet(P_EMOTION,EMOTION_NOAIR3);
	
	// goat
	idx2 = ObjFind(1001);
	ObjSet(idx2,O_DRAW,1);
	while(true)
	{
		x = ObjGet(idx2,O_X);
		x+=4;
		ObjSet(idx2,O_X,x);
		ObjPresent(idx2); // comming from the first room
		WaitFramesClearKeys(2);
		if(x>=PlayerGet(P_X)-24) break;
	}
	ObjSet(idx2,O_ANIM,0);
	PlayerSet(P_EMOTION,0);
	PlayerEnterJump(1,DIZ_POW*2);
	
	// the end
	WaitTime(2);
	OpenDialogFinish();
}

// make the player walk to posx coordinate
// posx must be reachable (multiple of 4 pixels)
func PlayerWalkTo( posx )
{
	while(true)
	{
		ClearKeys();
		x = PlayerGet(P_X);
		if(x<posx)
			SetKey(KEY_RIGHT,1);
		else
		if(x>posx)
			SetKey(KEY_LEFT,1);
		else
			return;
		stop;
	}
}

Homework

Creating nice cutscenes requires more patience than programming skills. As you could see from the above example, only simple and repetitive techniques were used. Try to play a little and do a small cutscene of your own, to make sure you got it's basics.